8.х Остатки по дням.

Здравствуйте, подскажите.
Делаю запрос.

Код:

ВЫБРАТЬ
    ХозрасчетныйОстаткиИОбороты.Счет,
    ХозрасчетныйОстаткиИОбороты.Субконто1,
    ХозрасчетныйОстаткиИОбороты.Субконто2,
    ХозрасчетныйОстаткиИОбороты.Организация,
    ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокКт КАК СуммаКонечныйОстатокКт,
    ХозрасчетныйОстаткиИОбороты.Период КАК Период
ИЗ
    РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, День, , Счет = &Счет, , Организация = &Организация) КАК ХозрасчетныйОстаткиИОбороты
ГДЕ
    ХозрасчетныйОстаткиИОбороты.Субконто2 = &Субконто2

УПОРЯДОЧИТЬ ПО
    ХозрасчетныйОстаткиИОбороты.Период
ИТОГИ ПО
    Период ПЕРИОДАМИ(ДЕНЬ, , )

но у меня остатки по дням не выходит, выводит только то когда был приход.
А нужно на каждый день, где ошибка в запросе или что я не доделал?

Запрос написан верно и выдает верный результат.
СКД умеет делать вывод так, как вам нужно.

сейчас попробую.

Код:

ВЫБРАТЬ РАЗРЕШЕННЫЕ
    КалендарныеГрафики.ДатаГрафика
ПОМЕСТИТЬ ВТ_Дни
ИЗ
    РегистрСведений.КалендарныеГрафики КАК КалендарныеГрафики
ГДЕ
    КалендарныеГрафики.ДатаГрафика МЕЖДУ &НачалоПериода И &КонецПериода
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ХозрасчетныйОстаткиИОбороты.Период КАК День,
    ХозрасчетныйОстаткиИОбороты.Субконто1 КАК Контрагент,
    ХозрасчетныйОстаткиИОбороты.Субконто2 КАК Договор,
    ХозрасчетныйОстаткиИОбороты.Счет,
    ХозрасчетныйОстаткиИОбороты.Организация,
    ХозрасчетныйОстаткиИОбороты.СуммаКонечныйОстатокКт КАК КонечныйОстатокКт
ПОМЕСТИТЬ ВТ_Остатки
ИЗ
    РегистрБухгалтерии.Хозрасчетный.ОстаткиИОбороты(&НачалоПериода, &КонецПериода, День, ДвиженияИГраницыПериода, Счет = &Счет, , Субконто2 = &Субконто2) КАК ХозрасчетныйОстаткиИОбороты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ РАЗРЕШЕННЫЕ
    ВТ_Дни.ДатаГрафика КАК ДатаГрафика,
    МАКСИМУМ(ВТ_Остатки.День) КАК ДатаОстатка
ПОМЕСТИТЬ ВТ_ДатыОстатка
ИЗ
    ВТ_Дни КАК ВТ_Дни
        ЛЕВОЕ СОЕДИНЕНИЕ ВТ_Остатки КАК ВТ_Остатки
        ПО ВТ_Дни.ДатаГрафика >= ВТ_Остатки.День

СГРУППИРОВАТЬ ПО
    ВТ_Дни.ДатаГрафика
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
    ВТ_ДатыОстатка.ДатаГрафика КАК ДатаГрафика,
    ВТ_Остатки.Контрагент,
    ВТ_Остатки.Договор,
    ВТ_Остатки.Счет,
    ВТ_Остатки.Организация,
    ВТ_Остатки.КонечныйОстатокКт,
    ВЫБОР
        КОГДА ВТ_ДатыОстатка.ДатаГрафика = &КонецПериода
            ТОГДА ВТ_Остатки.КонечныйОстатокКт
        ИНАЧЕ 0
    КОНЕЦ КАК ОстатокИтоговый
ИЗ
    ВТ_ДатыОстатка КАК ВТ_ДатыОстатка
        ВНУТРЕННЕЕ СОЕДИНЕНИЕ ВТ_Остатки КАК ВТ_Остатки
        ПО ВТ_ДатыОстатка.ДатаОстатка = ВТ_Остатки.День

УПОРЯДОЧИТЬ ПО
    ДатаГрафика

Вот так получилось без СКД.

--- Объединение сообщений, 15 окт 2014 ---

Спасибо, сделал.